FB20 MAIN PRS : Main code of spotting press

 

 

 

Netzwerk 1: PRS Initialisation

O "M00 Init"

ON "M00 OB1 FirstCycle"

SPBN m000

L ''

T #STEP_BITS

UN "M00 Init"

BEB

T "M00 MD20"

T "M00 MD24"

T "M00 MW28"

BEA

 

 

 

Netzwerk 2: Fault acknowledgement

m000: O "HMI KEY".PRS.F1_AckKey

O "M00 OB1 FrstCyclePuse"

FP "M00 ACK FP"

= "M00 ACK Imp"

 

 

 

Netzwerk 3: Call main station safety program

CALL "Main_Safety_FB21", "Main_Safety_DB21"

 

 

 

Netzwerk 4: Safety light curtain

UN "E00 OSSD1 E9181 RM"

U "Clock_1Hz"

O "E00 OSSD1 E9181 RM"

= "A00 LV1 S51 SigLmp"

 

UN "E00 OSSD1 E9183 RM"

U "Clock_1Hz"

O "E00 OSSD1 E9181 RM"

= "A00 LV2 S52 SigLmp"

 

UN "E00 OSSD1 E9185 RM"

U "Clock_1Hz"

O "E00 OSSD1 E9185 RM"

= "A00 LV3 S53 SigLmp"

 

UN "E00 OSSD2 B9180 M"

U "Clock_1Hz"

O "E00 OSSD2 B9180 M"

= "A00 LV4 S54 SigLmp"

 

 

 

Netzwerk 5: Control voltage on off

O "E00 Steu EIN"

O "E00 1M4 FdBack"

U "E00 DC24L4 RM"

UN "DI OUT PRS"."1M4".GenFlt

= "M00 CntrlVoltage onoff"

 

U "E00 1M4 FdBack"

= "A00 CnrlVolt SigLmp"

 

 

 

Netzwerk 6: PRS SEQ1 start, stop, hold

ON "M00 Enabled"

O "M00 OM MANUAL"

= #SEQ1.S.steph

 

UN "M00 RunHomPos"

U "M00 SEQ1 Start"

= #SEQ1.S.steps

 

-> CALL #SEQ1

ADR :=30

FC_NO :=21

 

 

 

Netzwerk 7: PRS FLT faults monitoring

-> CALL #FLT

FLT_ACK :="M00 ACK Imp"

IMP_100MS :="M00 Imp 10Hz"

FLT_MODULE :="M00 FltCmpltMaIS"

 

 

 

Netzwerk 8: Faults (red lamp)

U "M00 FltCmpltMaIS"

S "M00 FltCmpltMaSR"

UN "M00 FltCmpltMaSR"

UN "M00 Flt ACK"

SPB m001

U "M00 FltCmpltMaSR"

U "M00 ACK Imp"

S "M00 Flt ACK"

UN "M00 FltCmpltMaIS"

U "M00 Flt ACK"

R "M00 FltCmpltMaSR"

R "M00 Flt ACK"

m001: U "M00 FltCmpltMaSR"

UN "M00 Flt ACK"

U "Clock_0.5Hz"

O

U "M00 FltCmpltMaSR"

U "M00 Flt ACK"

= "A00 H55 FLT SigLmp"

 

 

 

Netzwerk 9: Automatic (green lamp)

U "M00 Auto CmpltMa run"

= "A00 H56 AUTO SigLmp"

 

 

 

Netzwerk 10: Query moduls home position

U "M01 HomPos"

U "M03 HomPos"

= "M00 HomPos"

S "M00 HomPosSR"

O #SET.S.steps

R "M00 HomPosSR"

 

 

 

Netzwerk 11: Start operating mode 'automatic'

O "M00 HomPos"

O "M00 HomPosSR"

U "E10 SS S02 Auto"

= "M00 OM AUTO"

R "M00 OM HOME POS"

R "M00 Manu CmpltMa run"

 

O "M00 HomPosSR"

U "M00 OM AUTO"

U "M00 F5 AUTO start"

S "M00 Auto CmpltMa run"

U "M00 Auto CmpltMa run"

FP "M00 TrnsSysRun FP"

= "M00 TrnsSysRun Imp"

 

 

 

Netzwerk 12: Start operating mode 'manual'

U "E10 SS S01 Hand"

U "HMI KEY".PRS.F5_Start

S "M00 Manu CmpltMa run"

R "M00 Auto CmpltMa run"

 

U "E10 SS S01 Hand"

R "M00 OM HOME POS"

 

 

 

Netzwerk 13: Start "home position" complete machine

U "HMI KEY".PRS.F7_OM_HOM_POS_ON

UN "E10 SS S01 Hand"

UN "M00 HomPos"

S "M00 OM HOME POS"

S "M00 OM AUTO"

R "M00 OM MANUAL"

R "M00 Manu CmpltMa run"

 

U "HMI KEY".PRS.F5_Start

U "M00 OM HOME POS"

U "M00 CntrlVoltage onoff"

UN "M00 FltCmpltMaSR"

U #SET.S.S0

S #SET.S.steps

 

ON "M00 OM HOME POS"

O "HMI KEY".PRS.F8_Stop

R #SET.S.steps

 

U "M00 FltCmpltMaSR"

= #SET.S.steph

 

CALL #SET

ADR :=0

FC_NO :=20

 

 

 

Netzwerk 14: Stop all operating mode

O "M00 FltCmpltMaSR"

O "M00 F8 AUTO stop"

ON "M00 CntrlVoltage onoff"

ON "E00 9S1 NH Pult CH1"

ON "E00 DC24L4 RM"

ON "E10 SS S02 Auto"

R "M00 Auto CmpltMa run"

 

U "M00 Manu CmpltMa run"

U "HMI KEY".PRS.F8_Stop

ON "M00 CntrlVoltage onoff"

ON "E10 SS S01 Hand"

ON "E00 9S1 NH Pult CH1"

R "M00 Manu CmpltMa run"

 

 

 

Netzwerk 15: Show key colour on HMI

O "M00 Manu CmpltMa run"

O #SET.S.steps

= "HMI KEY".PRS.Show_KeyColour

 

O "E10 SS S01 Hand"

O "M00 OM HOME POS"

= "HMI KEY".PRS.Show_Key

 

 

 

Netzwerk 16: Enable process number whilst manual mode

LAR1 P##Module_No

L ''

T D [ AR1 , P#0.0 ]

L #HMI_Module_No

+AR1

U "M00 Manu CmpltMa run"

= DIX [ AR1 , P#0.0 ]

 

 

 

Netzwerk 17: Enable running of assembly module

O #Module_No[1]

O "M00 Inch CmpltMa Imp"

O "M00 Auto CmpltMa run"

= "M00 Enabled"

= "M01 Enabled"

 

O #Module_No[2]

O "M00 Inch CmpltMa Imp"

O "M00 Auto CmpltMa run"

= "M02 Enabled"

 

O #Module_No[3]

O "M00 Inch CmpltMa Imp"

O "M00 Auto CmpltMa run"

= "M03 Enabled"

 

O #Module_No[4]

O "M00 Inch CmpltMa Imp"

O "M00 Auto CmpltMa run"

= "M04 Enabled"

 

O #Module_No[5]

O "M00 Inch CmpltMa Imp"

O "M00 Auto CmpltMa run"

= "M05 Enabled"

 

 

 

Netzwerk 18: PRS STEP.SEQ1_Start

U "M00 TrnsSysRun Imp"

U "M00 Auto CmpltMa run"

S #STEP.SEQ1_Start

BEB

U #STEP.SEQ1_Start

SPBN S1

UN "M00 RunHomPos"

UN "M00 SEQ1 Active"

S "M00 SEQ1 Start"

 

U "M00 SEQ1 Active"

R #STEP.SEQ1_Start

S #STEP.SEQ1_Running

SPA COM

 

 

 

Netzwerk 19: PRS STEP.SEQ1_Running

S1: U #STEP.SEQ1_Running

SPBN S2

U "M00 SEQ1 Done"

R #STEP.SEQ1_Running

S #STEP.SEQ1_Done

SPA COM

 

 

 

Netzwerk 20: PRS STEP.Done

S2: U #STEP.SEQ1_Done

SPBN S3

R "M00 SEQ1 Start"

R "M00 SEQ1 Done"

R #STEP.SEQ1_Done

S #STEP.SEQ1_Write

BEA

 

 

 

Netzwerk 21: PRS STEP.Write

S3: U #STEP.SEQ1_Write

SPBN COM

R "M00 SEQ1 WP1 DnOK"

R "M00 SEQ1 DoWP1" // nur bei RFID

R #STEP.SEQ1_Write

R "M00 Auto CmpltMa run"

SPA m004

 

 

 

Netzwerk 22: PRS Run-Time

COM: U "M00 Active"

SPB m003

L ''

T #RunTimeCounter_seq1

U "HMI KEY".P01.F3_GoToStep

U "M00 Manu CmpltMa run"

O "M00 Auto CmpltMa run"

S #STEP.SEQ1_Start

SPA m004

m003: U "M00 Imp 10Hz"

U "M00 Enabled"

SPBN m004

L #RunTimeCounter_seq1

+ 1

T #RunTimeCounter_seq1

 

 

 

Netzwerk 23: PRS SEQ1 Running

m004: O #STEP.SEQ1_Start

O #STEP.SEQ1_Running

O #STEP.SEQ1_Done

O #STEP.SEQ1_Write

= "M00 Active"

 

OB1 MAIN : Main program sweep (cycle)

 

 

 

Netzwerk 1: 8-bits impulse evaluation

L "sav_clock_byte"

L "clock_byte"

T "sav_clock_byte"

XOW

L "clock_byte"

UW

T "M00 PLC Impulse"

 

 

 

Netzwerk 2: CALL distributor

CALL "FB MAIN PRS", "DI MAIN PRS"

CALL "FB HMI PRS", "DI HMI PRS"// know how protected

CALL "FB MAIN P01", "DI MAIN P01"

CALL "FB MAIN P02", "DI MAIN P02"

CALL "FB MAIN P03", "DI MAIN P03"

CALL "FB MAIN P04", "DI MAIN P04"

CALL "FB MAIN P05", "DI MAIN P05"

 

-> CALL "FB OUT P01", "DI OUT P01"

-> CALL "FB OUT P02", "DI OUT P02"

-> CALL "FB OUT P03", "DI OUT P03"

-> CALL "FB OUT P04", "DI OUT P04"

-> CALL "FB OUT P05", "DI OUT P05"

-> CALL "FB OUT PRS", "DI OUT PRS"

 

 

 

Netzwerk 3: Switch off all derivers before SEQ on

UN "M01 RunHomPos"

UN "M03 RunHomPos"

U "M00 Manu CmpltMa run"

O "M00 Init"

O "M00 OB1 FrstCyclePuse"

FN "M00 OB1 FrstCycle FN"

SPBN m004

CALL "FC INIT PRS"

 

 

 

Netzwerk 4: First cycle evaluation

m004: UN "M00 OB1 FirstCycle"

L s5t#1s

SV "T00 OB1 FirstCycle"

U "T00 OB1 FirstCycle"

= "M00 OB1 FrstCyclePuse"

 

U "M00 log 1"

L s5t#2s

SE "T00 OB1 FrstCycle"

U "T00 OB1 FrstCycle"

= "M00 OB1 FirstCycle"

 

 

 

Netzwerk 5: Flag logic =0

U "M00 log 0"

R "M00 log 0"

SET

= "M00 log 1"

 

 

Home

 

Erfahrung

 

Referenzen

 

Sondermaschinen

 

MSR-Maschinen

 

SPS-Programmierung

 

Visualisierung HMI

 

Elektro CAD

 

Leistungsprofil

 

Personalia

 

SW-Development

 

Dokumentation

 

 

 

Impressum & DSGVO

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

 

To go to next HMI image use the touch-buttons; some of them are interactive.