SEQ303 : Execute clocking valves in SEQ241 with SBT

[hit  <- on your browser to return]

Network 1: Define SSM last step

#SSM(LAST_STEP := 10);

Network 1: Jump distributor corresponds to SEQ303

CASE #SSM.S.stepact OF

    0: // waiting for sequencer to start

        #SSM.S.stepd := #SSM.S.steps;

        #Done :=

        "DI OUT P01".V101.CmdExe_WP :=

        "DI OUT P01".V102.CmdExe_WP :=

        "DI OUT P01".V103.VLV_O.CmdExe_WP :=

        "DI OUT P01".V108.CmdExe_WP :=

        "DI OUT P01".V109.CmdExe_WP :=

        "DI OUT P02".V202.VLV_O.CmdExe_WP :=

        "DI OUT P03".V304.VLV_O.CmdExe_WP :=

        "DI OUT P03".V307.VLV_O.CmdExe_WP :=

        "DI OUT P03".V311.VLV_O.CmdExe_WP :=

        "DI OUT P03".V313.VLV_O.CmdExe_WP :=

        "DI OUT P03".V320.CmdExe_WP :=

        "DI OUT P03".V315.CmdExe_WP := FALSE;

    1: // waiting for ready to start

        #SSM.S.stepd :=

        "DI OUT P01".G120C.NexDrv_DlyOn

        AND "DI OUT P02".M201.NexDrv_DlyOn

        AND "DI OUT P02".G220C.DRV.Support.LampON

        AND "DI OUT P03".V312.Output >= "HMI KEY".SetPoint.V312_Product_inlet;

    2: // V102 gully WP

        "DI OUT P01".V102.CmdExe_WP := "HMI KEY".P01.V102.F12_Enable_WP;

        IF #SSM.S.stepfc THEN

            #SSM.S.c1.set := 50;

        ELSE

            #SSM.S.c1.start := "A01 V102 WP";

            #SSM.S.stepd := #SSM.S.c1.done;

        END_IF;

    3: // V102 gully WP, V108 seat above WP, V315 seat below WP

        "DI OUT P01".V108.CmdExe_WP := "HMI KEY".P01.V108.F12_Enable_WP AND NOT #SSM.S.c1.done;

        "DI OUT P03".V315.CmdExe_WP := "HMI KEY".P03.V315.F12_Enable_WP AND NOT #SSM.S.c1.done;

        IF #SSM.S.stepfc THEN

            #SSM.S.c1.set := 50;

        ELSE

            #SSM.S.c1.start := "A01 V108 WP" AND "A03 V315 WP";

            #SSM.S.stepd := "A01 V102 WP" AND NOT ("A01 V108 WP" OR "A03 V315 WP") AND #SSM.S.c1.done;

        END_IF;

    4: // V102 CIP gully WP, V101 gully WP

        "DI OUT P01".V101.CmdExe_WP := "HMI KEY".P01.V101.F12_Enable_WP AND NOT #SSM.S.c1.done;

        IF #SSM.S.stepfc THEN

            #SSM.S.c1.set := 50;

        ELSE

            #SSM.S.c1.start := "A01 V101 WP";

            #SSM.S.stepd := "A01 V102 WP" AND NOT "A01 V101 WP" AND #SSM.S.c1.done;

        END_IF;

    5: // V102 gully WP, V320 seat below WP, V109 seat below WP, V202 bypass HE2 WP

        "DI OUT P03".V320.CmdExe_WP := "HMI KEY".P03.V320.F12_Enable_WP AND NOT #SSM.S.c1.done;

        "DI OUT P01".V109.CmdExe_WP := "HMI KEY".P01.V109.F12_Enable_WP AND NOT #SSM.S.c1.done;

        "DI OUT P02".V202.VLV_O.CmdExe_WP := "HMI KEY".P02.V202.F12_Enable_WP AND NOT #SSM.S.c1.done;

        IF #SSM.S.stepfc THEN

            #SSM.S.c1.set := 50;

        ELSE

            #SSM.S.c1.start := "DI OUT P02".V202.FB_WP AND "A01 V109 WP" AND "A03 V320 WP";

            #SSM.S.stepd := "DI OUT P02".V202.FB_HP AND "A01 V102 WP" AND NOT ("A01 V109 WP" OR "A03 V320 WP") AND #SSM.S.c1.done;

        END_IF;

    6: // V102 gully WP, V313 double seat WP, V311 inlet WP

        "DI OUT P03".V311.VLV_O.CmdExe_WP := "HMI KEY".P03.V311.F12_Enable_WP;

        "DI OUT P03".V313.VLV_O.CmdExe_WP := "HMI KEY".P03.V313.F12_Enable_WP;

        "DI OUT P01".V102.CmdExe_WP := "HMI KEY".P02.V202.F12_Enable_WP AND NOT #SSM.S.c1.done;

        IF #SSM.S.stepfc THEN

            #SSM.S.c1.set := 60;

        ELSE

            #SSM.S.c1.start := "A01 V102 WP";

            #SSM.S.stepd := NOT "A01 V102 WP" AND "DI OUT P03".V313.FB_WP AND "DI OUT P03".V311.FB_WP AND #SSM.S.c1.done;

        END_IF;

    7: // V313 inlet WP, V311 CIP inlet WP

        IF #SSM.S.stepfc THEN

            #SSM.S.c1.set := 50;

            #SSM.S.c1.start := TRUE;

        ELSE

            #SSM.S.stepd := "DI OUT P03".V313.FB_WP AND "DI OUT P03".V311.FB_WP AND #SSM.S.c1.done;

        END_IF;

    8: // V307 gully WP, V313 inlet WP, V311 CIP inlet WP, V304 bypass WP

        "DI OUT P03".V304.VLV_O.CmdExe_WP := "HMI KEY".P03.V304.F12_Enable_WP AND NOT #SSM.S.c1.done;

        "DI OUT P03".V307.VLV_O.CmdExe_WP := "HMI KEY".P03.V307.F12_Enable_WP;

        IF #SSM.S.stepfc THEN

            #SSM.S.c1.set := 50;

        ELSE

            #SSM.S.c1.start := "DI OUT P03".V304.FB_WP;

            #SSM.S.stepd := "DI OUT P03".V307.FB_WP AND "DI OUT P03".V311.FB_WP

            AND "DI OUT P03".V313.FB_WP AND "DI OUT P03".V304.FB_HP AND #SSM.S.c1.done;

        END_IF;

    9: // V307 gully WP, V102 gully WP, V313 inlet WP, V311 inlet WP

        "DI OUT P01".V102.CmdExe_WP := "HMI KEY".P01.V102.F12_Enable_WP;

        "DI OUT P03".V313.VLV_O.CmdExe_WP := "HMI KEY".P03.V313.F12_Enable_WP AND NOT #SSM.S.c1.done;

        "DI OUT P03".V311.VLV_O.CmdExe_WP := "HMI KEY".P03.V311.F12_Enable_WP AND NOT #SSM.S.c1.done;

        IF #SSM.S.stepfc THEN

            #SSM.S.c1.set := 50;

        ELSE

            #SSM.S.c1.start := "DI OUT P03".V313.FB_WP AND "DI OUT P03".V313.FB_WP;

            #SSM.S.stepd := "DI OUT P03".V311.FB_HP AND "DI OUT P03".V313.FB_HP AND "A01 V102 WP" AND #SSM.S.c1.done;

        END_IF;

    10: // V307 gully WP, V102 gully WP + SBT drip off

        "DI OUT P01".V102.CmdExe_WP := "DI OUT P03".V307.VLV_O.CmdExe_WP := "E03 LS307 min";

        IF #SSM.S.stepfc THEN

            #SSM.S.c1.set := 50;

        ELSE

            #SSM.S.c1.start := "DI OUT P03".V307.FB_HP AND NOT "A01 V102 WP";

            #SSM.S.stepd := #Done := #SSM.S.c1.done;

        END_IF;

END_CASE;