Home

Erfahrung

Referenzen

Sondermaschinen

MSR-Maschinen

SPS-Programmierung

Visualisierung HMI

Elektro CAD

Leistungsprofil

Personalia

SW-Development

Dokumentation

Impressum & DSGVO

FB48 MAN P01 :  P02 manual program (FDR)

Netzwerk 1: S120_M Feeder drive (master) - enable

IF #ST_MANU AND NOT #SUPPORT_SEQ THEN

    // Assing slider velocity slider set value

    IF NOT #S120_M.Slider_Velocity_on THEN

        #S120_M.Slider_Velocity_on := FALSE;

    ELSIF "DI OUT P02".S120_M."MC MoveJog".Busy OR NOT "DI OUT P02".S120_M.DRV.MC_MoveAbsolute.Busy THEN

        #tmp_sav_lword := #S120_M.ManuVelocity_2_sav XOR #S120_M.ManuVelocity_2;

        #S120_M.ManuVelocity_2_sav := #S120_M.ManuVelocity_2;

        #S120_S.Slider_Velocity_on := FALSE;

        IF #tmp_sav_lword <> 0 THEN

            #tmp_sav_lword := #tmp_sav_lword AND #S120_M.ManuVelocity_2_sav;

            IF #tmp_sav_lword >= 0 THEN

                "HMI KEY".P02.GLB.SliderControl := LINT_TO_INT(#S120_M.ManuVelocity_2);

            ELSE

                RETURN;

            END_IF;

        ELSE

            #S120_M.ManuVelocity_2_sav := #S120_M.ManuVelocity_2 := INT_TO_LINT("HMI KEY".P02.GLB.SliderControl);

        END_IF;

    END_IF;

    // Set value velocity

    "DI OUT P02".S120_M.DRV.Support.SetVelo := LINT_TO_LREAL(#S120_M.ManuVelocity_2);

    // Jog fast WP (toggle function)

    IF "HMI KEY".P02.S120_M.F19_Jog_fast_WP AND NOT #S120_M.Jog_fast_WP_REg THEN

        #Support.S120_M_Jog_fast_WP := NOT #Support.S120_M_Jog_fast_WP;

        #Support.S120_M_Jog_fast_HP := FALSE;

        // Jog fast HP (toggle function)

    ELSIF "HMI KEY".P02.S120_M.F20_Jog_fast_HP AND NOT #S120_M.Jog_fast_HP_REg THEN

        #Support.S120_M_Jog_fast_HP := NOT #Support.S120_M_Jog_fast_HP;

        #Support.S120_M_Jog_fast_WP := FALSE;

        // Jog slow WP (button function)

    ELSIF "HMI KEY".P02.S120_M.F3_Jog_slow_WP OR "DI OUT P02".Support.S120_M_FEg_Halt_Imp OR "HMI KEY".P02.S120_M.F21_HALT_Epos THEN

        #S120_M.CmdExe_slow_WP := "HMI KEY".P02.S120_M.F3_Jog_slow_WP;

        #Support.S120_M_Jog_fast_HP := #Support.S120_M_Jog_fast_WP := FALSE;

        // Jog slow HP (button function)

    ELSIF "HMI KEY".P02.S120_M.F4_Jog_slow_HP THEN//OR "DI OUT P02".Support.S120_M_FEg_Halt_Imp THEN //OR "HMI KEY".P02.S120_M.F21_HALT_Epos THEN

        #S120_M.CmdExe_slow_HP := "HMI KEY".P02.S120_M.F4_Jog_slow_HP;

        #Support.S120_M_Jog_fast_HP := #Support.S120_M_Jog_fast_WP := FALSE;

    ELSE

        #S120_M.CmdExe_slow_HP :=

        #S120_M.CmdExe_slow_WP := FALSE;

    END_IF;

    // Jog fast WP/HP (Assigning rising edge)

    #S120_M.Jog_fast_WP_REg := "HMI KEY".P02.S120_M.F19_Jog_fast_WP;

    #S120_M.Jog_fast_HP_REg := "HMI KEY".P02.S120_M.F20_Jog_fast_HP;

END_IF;

// Calculate remainder MovRelaTargtPos after sequencer stop-interruption (option)

IF "HMI KEY".P02.S120_M.F21_HALT_Epos AND "HMI KEY".P02.S120_M.F10_Execute THEN

    "DI OUT P02".S120_M.DRV.MC_MoveRelative.Distance := "DI OUT P02".S120_M.DRV.Support.SavTrgtPos - "DI OUT P02".S120_M.DRV.Support.ActPos;

END_IF;

// Enabling HP

"HMI KEY".P02.S120_M.F11_Enable_HP :=

#S120_M.ManuVelocity_2 >= 0

AND "DI OUT P02".S120_M.DRV.Support.InOperation // ready

AND NOT ("DI OUT P02".S120_M.DRV.Support.SW_EndLim_Min OR "DI OUT P02".S120_M.Com_FLT);

// Enabling WP

"HMI KEY".P02.S120_M.F12_Enable_WP :=

#S120_M.ManuVelocity_2 >= 0

AND "DI OUT P02".S120_M.DRV.Support.InOperation // ready

AND NOT "DI OUT P02".S120_M.DRV.Support.SW_EndLim_Max AND NOT "DI OUT P02".S120_M.Com_FLT;

// Opitical signaling (option for HMI)

"HMI KEY".P02.S120_M.F14_SupportSig_WP := #"S120_M".CmdExe_slow_fast_WP AND NOT "DI OUT P02".S120_M."MC MoveJog".Busy;

"HMI KEY".P02.S120_M.F13_SupportSig_HP := #"S120_M".CmdExe_slow_fast_HP AND NOT "DI OUT P02".S120_M."MC MoveJog".Busy;

Netzwerk 2: S120_S Feeder drive (slave) - enable

IF #ST_MANU AND NOT #SUPPORT_SEQ THEN

    IF NOT #S120_M.Slider_Velocity_on THEN

        IF NOT #S120_S.Slider_Velocity_on THEN

            #S120_S.Slider_Velocity_on := FALSE;

        END_IF;

    END_IF;

    // Manual mode velocity

    "DI OUT P02".S120_S.DRV.MC_MoveJog.Velocity := #S120_S.ManuVelocity_1;

    #S120_S.CmdExe_slow_WP := "HMI KEY".P02.S120_S.F3_Jog_slow_WP AND #S120_S.Slider_Velocity_on;

    #S120_S.CmdExe_slow_HP := "HMI KEY".P02.S120_S.F4_Jog_slow_HP AND #S120_S.Slider_Velocity_on;

END_IF;

// Enabling HP/WP

"HMI KEY".P02.S120_S.F11_Enable_HP := "HMI KEY".P02.S120_S.F12_Enable_WP := "DI OUT P02".S120_S.DRV.Support.InOperation AND NOT "DI OUT P02".S120_S.Com_FLT;

Netzwerk 3: C01 Feeder cylinder - enable

"HMI KEY".P02.C01.F11_Enable_HP := "HMI KEY".P02.C01.F12_Enable_WP :=

"DI OUT P02".C01.VLV_OC.SetIdleTime > 0 AND NOT "DI OUT P02".C01.com_flt AND "E00 AirPrsr ok";

Netzwerk 4: Monitoring pneumatics manual operation ***

IF NOT #ST_MANU THEN

    RETURN;

ELSIF #MODULE_HP AND NOT #Support.HomPos_REg THEN

    "M02 Init" := TRUE;

END_IF;

#Support.HomPos_REg := #MODULE_HP;

IF #SUPPORT_SEQ THEN

    RETURN;

END_IF;

Netzwerk 5: S120 M Feeder (master) - execute

#"S120_M".CmdExe_slow_fast_WP :=

"HMI KEY".P02.S120_M.F12_Enable_WP

AND NOT "HMI KEY".P02.S120_M.F21_HALT_Epos

AND (#Support.S120_M_Jog_fast_WP OR #"S120_M".CmdExe_slow_WP);

#"S120_M".CmdExe_slow_fast_HP :=

"HMI KEY".P02.S120_M.F11_Enable_HP

AND NOT "HMI KEY".P02.S120_M.F21_HALT_Epos

AND (#Support.S120_M_Jog_fast_HP OR #"S120_M".CmdExe_slow_HP);

Netzwerk 6: S120 S Feeder (slave) - execute

#S120_S.CmdExe_slow_fast_WP := "HMI KEY".P02.S120_S.F12_Enable_WP AND #S120_S.CmdExe_slow_WP;

#S120_S.CmdExe_slow_fast_HP := "HMI KEY".P02.S120_S.F11_Enable_HP AND #S120_S.CmdExe_slow_HP;

Netzwerk 7: C01 Feeder cylinder - execute

"DI OUT P02".C01.VLV_OC.CmdExe_WP := "HMI KEY".P02.C01.F12_Enable_WP

AND NOT "HMI KEY".P02.C01.F1_HP AND ("HMI KEY".P02.C01.F2_WP OR "DI OUT P02".C01.FB_WP);

"DI OUT P02".C01.VLV_OC.CmdExe_HP := "HMI KEY".P02.C01.F11_Enable_HP

AND NOT "HMI KEY".P02.C01.F2_WP AND ("HMI KEY".P02.C01.F1_HP OR "DI OUT P02".C01.FB_HP);

To go to next HMI image use the touch buttons; some of them are interactive.