Home

Erfahrung

Referenzen

Sondermaschinen

MSR-Maschinen

SPS-Programmierung

Visualisierung HMI

Elektro CAD

Leistungsprofil

Personalia

SW-Development

Dokumentation

Impressum & DSGVO

To go to next HMI image use the touch buttons; some of them are interactive.

FB38 MAN P01 :  P01 Manual CAM control

Netzwerk 1: V90M MC_PositioningAxis - enable

IF #ST_MANU AND NOT #SUPPORT_SEQ THEN

    IF "DI MAIN GLB".M00.CmpltMaRun_Imp THEN

        #V90M.ManualVelocity_1 := "DI OUT P01".V90M.DRV.Support.SetVelo; // mm/s

        // Evaluate SliderControl

    ELSIF "DI OUT P01".V90M.DRV.MC_MoveJog.Busy AND NOT ("DI OUT P01".V90M.DRV.MC_MoveAbsolute.Busy OR "DI OUT P01".V90M.DRV.MC_MoveRelative.Busy) THEN

        IF #V90M.ManualVelocity_1 < 500.0 AND "HMI KEY".P01.V90M.F2_WP AND "M00_Imp_2.5Hz" THEN

            #V90M.ManualVelocity_1 := #V90M.ManualVelocity_1 + 1.0;

        ELSIF #V90M.ManualVelocity_1 > 0.0 AND "HMI KEY".P01.V90M.F1_HP AND "M00_Imp_2.5Hz" THEN

            #V90M.ManualVelocity_1 := #V90M.ManualVelocity_1 - 1.0;

        END_IF;

    END_IF;

    // Assign velocity manual mode

    "DI OUT P01".V90M.DRV.Support.SetVelo := #V90M.ManualVelocity_1; // mm/s

    // On switching MoveJog

    IF "HMI KEY".P01.V90M.F19_Jog_fast_WP AND NOT #V90M.Jog_fast_WP_REg THEN

        #V90M.CmdExe_slow_fast_WP := "HMI KEY".P01.V90M.F12_Enable_WP;

    END_IF;

    #V90M.Jog_fast_WP_REg := "HMI KEY".P01.V90M.F19_Jog_fast_WP;

END_IF;

// Enabling drive

"HMI KEY".P01.V90M.F12_Enable_WP := "HMI KEY".P01.V90M.F11_Enable_HP := "DI OUT P01".V90M.DRV.Support.InOperation AND NOT "DI OUT P01".V90M.Com_FLT;

// Off switching MoveJog

IF "DI OUT P01".V90M.HALT_01 OR "HMI KEY".P01.V90M.F20_Jog_fast_HP OR "DI OUT P01".V90M.DRV.Support.SetVelo = 0 OR "DI OUT P01".CAM_DISC.Com_FLT OR "DI OUT P01".V90M.DRV.MC_MoveAbsolute.Busy OR "DI OUT P01".V90M.DRV.MC_MoveRelative.Busy THEN

    #V90M.CmdExe_slow_fast_WP := FALSE;

END_IF;

Netzwerk 2: V90SM MC_SynchronousAxis

IF #ST_MANU AND NOT #SUPPORT_SEQ THEN

    IF "DI MAIN GLB".M00.CmpltMaRun_Imp THEN

        #V90SM.ManualVelocity_1 := "DI OUT P01".V90SM.DRV.Support.SetVelo; // mm/s

    END_IF;

    // Manual mode velocity

    "DI OUT P01".V90SM.DRV.Support.SetVelo := #V90SM.ManualVelocity_1; // mm/s

    #V90SM.CmdExe_slow_fast_WP := "HMI KEY".P01.V90SM.F3_Jog_slow_WP AND "DI OUT P01".V90SM.DRV.Support.SetVelo > 0.0;

    #V90SM.CmdExe_slow_fast_HP := "HMI KEY".P01.V90SM.F4_Jog_slow_HP AND "DI OUT P01".V90SM.DRV.Support.SetVelo > 0.0;

END_IF;

// Enabling HP/WP

"HMI KEY".P01.V90SM.F11_Enable_HP := "HMI KEY".P01.V90SM.F12_Enable_WP := "DI OUT P01".V90SM.DRV.Support.InOperation AND NOT "DI OUT P01".V90SM.Com_FLT;

Netzwerk 3: V90S MC_SynchronousAxis - enable

IF #ST_MANU AND NOT #SUPPORT_SEQ THEN

    IF "DI MAIN GLB".M00.CmpltMaRun_Imp THEN

        #V90S.ManualVelocity_1 := "DI OUT P01".V90S.DRV.Support.SetVelo; // mm/s

    END_IF;

    // Manual mode velocity

    "DI OUT P01".V90S.DRV.MC_MoveJog.Velocity := #V90S.ManualVelocity_1; // mm/s

    #V90S.CmdExe_slow_fast_WP := "HMI KEY".P01.V90S.F3_Jog_slow_WP AND "DI OUT P01".V90S.DRV.MC_MoveJog.Velocity > 0.0 AND "HMI KEY".P01.V90S.F12_Enable_WP;

    #V90S.CmdExe_slow_fast_HP := "HMI KEY".P01.V90S.F4_Jog_slow_HP AND "DI OUT P01".V90S.DRV.MC_MoveJog.Velocity > 0.0 AND "HMI KEY".P01.V90S.F11_Enable_HP;

END_IF;

// Enabling HP/WP

"HMI KEY".P01.V90S.F11_Enable_HP := "HMI KEY".P01.V90S.F12_Enable_WP := "DI OUT P01".V90S.DRV.Support.InOperation AND NOT "DI OUT P01".V90S.Com_FLT;

Netzwerk 4: CAM_DISC Control - enable

IF #ST_MANU AND NOT #SUPPORT_SEQ THEN

    IF "DI MAIN GLB".M00.CmpltMaRun_Imp THEN

        #CAM_DISC.ManualVelocity_1 := "DI OUT P01".CAM_DISC.CAM.MC_CamIn.Velocity;

    ELSIF #V90M.ManualVelocity_1 < 100.0 AND "HMI KEY".P01.CAM_DISC.F2_WP AND "M00_Imp_2.5Hz" THEN

        #CAM_DISC.ManualVelocity_1 := #CAM_DISC.ManualVelocity_1 + 1.0;

    ELSIF #CAM_DISC.ManualVelocity_1 > 0.0 AND "HMI KEY".P01.CAM_DISC.F1_HP AND "M00_Imp_2.5Hz" THEN

        #CAM_DISC.ManualVelocity_1 := #CAM_DISC.ManualVelocity_1 - 1.0;

    END_IF;

    // Assign velocity manual mode

    IF "DI OUT P01".CAM_DISC.CAM.MC_CamIn.SyncProfileReference = 0 THEN

        "DI OUT P01".CAM_DISC.CAM.MC_CamIn.Velocity := #CAM_DISC.ManualVelocity_1; // mm/s

    ELSE

        "DI OUT P01".CAM_DISC.CAM.MC_CamIn.Velocity := #CAM_DISC.ManualVelocity_1 := -1.0;

    END_IF;

END_IF;

// Execute part travels in

#CAM_DISC.CmdExe_slow_WP := "HMI KEY".P01.CAM_DISC.F3_Jog_slow_WP AND "DI OUT P01".V90M.DRV.Support.LampON AND NOT "DI OUT P01".CAM_DISC.CAM.MC_CamIn.Busy;

// Enabling HP/WP

"HMI KEY".P01.CAM_DISC.F11_Enable_HP := NOT "DI OUT P01".CAM_DISC.CAM_OnOff AND "HMI KEY".P01.CAM_DISC.F12_Enable_WP;

"HMI KEY".P01.CAM_DISC.F12_Enable_WP := NOT "DI OUT P01".CAM_DISC.Com_FLT AND "DI OUT P01".V90S.DRV.MC_GearIn.InGear;

Netzwerk 5: V90 MC_OutputCam - enable

IF #ST_MANU AND NOT #SUPPORT_SEQ THEN

    IF "DI MAIN GLB".M00.CmpltMaRun_Imp THEN

        #V90.ManualVelocity_1 := "DI OUT P01".V90.DRV.Support.SetVelo; // mm/s

    END_IF;

    // Manual mode velocity condition

    IF "DI OUT P01".CAM_DISC.CAM.MC_OutputCam.CamOutput THEN

        "DI OUT P01".V90.DRV.Support.SetVelo := "DI OUT P01".V90M.DRV.Support.SetVelo;

    ELSE

        "DI OUT P01".V90.DRV.Support.SetVelo := #V90.ManualVelocity_1; // mm/s

        #V90.CmdExe_slow_fast_WP := "HMI KEY".P01.V90.F3_Jog_slow_WP AND "HMI KEY".P01.V90.F12_Enable_WP;

        #V90.CmdExe_slow_fast_HP := "HMI KEY".P01.V90.F4_Jog_slow_HP AND "HMI KEY".P01.V90.F11_Enable_HP;

    END_IF;

END_IF;

// Enabling HP/WP

"HMI KEY".P01.V90.F11_Enable_HP := "HMI KEY".P01.V90.F12_Enable_WP := "DI OUT P01".V90.DRV.Support.InOperation AND NOT "DI OUT P01".V90.Com_FLT;

// Stop moving towards WP/HP

IF "DI OUT P01".V90.HALT_01 OR "DI OUT P01".V90.DRV.MC_MoveVelocity.Busy OR "DI OUT P01".V90.DRV.Support.SetVelo = 0 THEN

    #V90.CmdExe_slow_fast_WP := #V90.CmdExe_slow_fast_HP := FALSE;

END_IF;

Netzwerk 6: Monitoring pneumatics manual operation ***

IF NOT #ST_MANU THEN

    RETURN;

ELSIF #MODULE_HP AND NOT #Support.HomPos_REg THEN

    "DI MAIN P01".M00.Init := TRUE;

END_IF;

#Support.HomPos_REg := #MODULE_HP;

"DI MAIN P01".M00.TOF_ModuleOFF_Pulse(IN := NOT #SUPPORT_SEQ AND #Support.HomPos_FEg,

PT := t#500ms);

#Support.HomPos_FEg := #SUPPORT_SEQ;

IF #SUPPORT_SEQ THEN

    RETURN;

END_IF;

Netzwerk 7: CAM_DISC Control - execute

"DI OUT P01".CAM_DISC.CAM.MC_MeasuringInput.Execute := "DI OUT P01".CAM_DISC.CAM.Support.ReadTo_ReStart AND "HMI KEY".P01.CAM_DISC.F11_Enable_HP

AND #CAM_DISC.CmdExe_slow_WP;